À la prochaine.

C'est pour ça que je vais rester pour l'instant sur la solution de pingouinux, elle reprend la même structure que mon post de départ.

@pingouinux
une dernière question:
Une chose que je ne comprends pas, c'est la raison pour laquelle k=0. Comme je procédais avec sed, je partais d'une valeur de 1 et choisissais le signe <= pour l'expr2. Si je mets ces valeurs, il me manque la 1ère ligne et j'obtiens une dernière vide. Cela vient du comportement de mapfile je suppose, mais j'ai du mal à en saisir la raison, l'option -t enlevant le retour à la ligne si j'ai bien compris (et surtout si le traducteur me l'a bien traduit ).

En tout cas je ne regrette pas d'avoir poster, en dehors d'avoir résolu mon problème de départ, vos expériences sont très enrichissantes. Merci encore à vous 2.
@+ sur le forum

awk 'pattern1 { actions }
pattern2 { actions }' fichier1 fichier2 ...

De base, awk fonctionne par ligne : une ligne = un enregistrement (on peut changer ce comportement)
Il applique à chaque enregistrement les couples pattern { actions }

Chaque enregistrement est découpé en champs ; par défaut, le séparateur est une suite de blancs (espaces ou tabulations). On peut accéder à ces champs par $1, $2 etc... L'enregistrement entier étant $0. Le dernier champ de l'enregistrement est $NF (NF étant une variable égale au nombre de champs de l'enregistrement)
Pour chaque ligne, si le pattern est vrai alors les actions correspondantes sont effectuées. Si pattern est faux, les actions correspondantes ne sont pas effectuées.

NR : variable contenant le numéro de l'enregistrement courant
FNR : variable contenant le numéro de l'enregistrement dans le fichier en cours d'analyse

awk analyse les fichiers dans l'ordre et donc, FNR est remis à 1 lorsque l'on commence à lire un nouveau fichier alors que NR continue à s'incrémenter. Par exemple, si on a passé à awk 2 fichiers de 10 lignes en paramètres, sur la dernière ligne du 2ème fichier, NR vaudra 20 alors que FNR vaudra 10.

Dans ma commande, NR == FNR est donc vrai seulement pour le 1er fichier, ici fichier3.
{ ligne3[$0]=1; next } est donc effectué pour chaque ligne de fichier3. Pour chaque ligne, on attribue la valeur 1 à un élément du tableau ligne3. Ce tableau est indicé par la chaîne de caractère qui compose la ligne. Puis on passe la commande next qui dit à awk de ne pas s'occuper des actions suivantes (ni des pattern) et de passer à l'enregistrement suivant. { getline ligne2 < "fichier2"; if (ligne3[ligne2]) print "TRUE"; else print "FALSE"; print $0; print ligne2 } n'est donc pas exécuté pour fichier3.
Si fichier3 contient ceci :

ligne 1 de fichier3
ligne 2 de fichier3

Une fois que awk aura analysé ce fichier, on aura 2 éléments dans le tableau ligne3 : ligne3["ligne 1 de fichier3"] et ligne3["ligne 2 de fichier3"]. Ces 2 éléments valent 1.

awk passe ensuite à l'analyse de fichier1.
NR == FNR est faux pour toutes les lignes de fichier1 : { ligne3[$0]=1; next } n'est donc plus exécuté.
{ getline ligne2 < "fichier2"; if (ligne3[ligne2]) print "TRUE"; else print "FALSE"; print $0; print ligne2 } est exécuté pour chaque ligne de fichier1 vu qu'il n'y a pas de pattern.

getline ligne2 < "fichier2" : chaque fois que cette commande est appelée, cela va attibuer une valeur à ligne2.
Si fichier2 contient ceci :

ligne 1 de fichier2
ligne 2 de fichier2

Au premier appel de getline, la variable ligne2 vaudra ligne 1 de fichier2 ; au 2ème appel, ligne2 vaudra ligne 2 de fichier2.
Ainsi, lorsque l'on traite la 1ère ligne de fichier1, ligne2 a pour valeur la 1ère ligne de fichier2. Lorsque l'on traite la 2ème ligne de fichier1, ligne2 a pour valeur la 2ème ligne de fichier2 et ainsi de suite.

if (ligne3[ligne2]) print "TRUE"; else print "FALSE" : cela permet de tester l'existence d'un élément du tableau ligne3. Si cet élément existe, cela veut dire qu'il y a une ligne en commun dans fichier2 et fichier3, on affiche donc TRUE. Si l'élément n'existe pas, on affiche FALSE.

print $0 : affiche la ligne en cours de fichier1
print ligne2 : affiche la valeur de ligne2

Sinon, voici la commande en un peu plus claire pour aider à la compréhension (parce que la syntaxe awk est souple) :

awk 'NR == FNR {
        ligne3[$0]=1
        next
     }
     {
        getline ligne2 < "fichier2"
        if (ligne3[ligne2]) {
           print "TRUE"
        }
        else {
           print "FALSE"
        }
        print $0
        print ligne2
     }' fichier3 fichier1

Et quasi la même en pas claire :

awk 'NR==FNR{ligne3[$0]=1;next}{getline ligne2<"fichier2";printf("%s\n%s\n%s\n",ligne3[ligne2]?"TRUE":"FALSE",$0,ligne2)}' fichier3 fichier1

La solution préférable est celle que tu comprends le mieux. Comme ça si tu veux y ajouter/modifier quelque chose, c'est plus simple.

L'avantage du awk par rapport à la solution de pingouinux, c'est que je ne lis qu'une fois fichier3 (mais en entier) alors que grep sur le fichier3 est appelé autant de fois qu'il y a de lignes dans fichier1 (mais le grep ne lit pas le fichier en entier du fait de l'option -q).

Sinon, je pense que awk serait plus rapide si les fichiers sont gros.

Et ne t'inquiète pas, même si pingouinux n'est pas d'accord avec moi, je ne l'étriperai pas !... Enfin pas tout de suite, car ses posts m'apprennent toujours plein de trucs... Par contre, une fois que j'aurai épuisé son savoir, je me gènerai pas !! gnac gnac gnac !

@tous les 2
Y a-t-il une solution préférable à l'autre? Ne vous étripez pas, ce n'est qu'une question.
Pour l'instant j'ai une préférence pour celle de pingouinux qui est plus dans mes capacités de compréhension.

Un grand grand MERCI pour vos solutions et vos explications, j'ai encore bien appris des choses grâce à vous .

• Voir help mapfile (synonyme de readarray, mais la doc est plus complète). Cette commande transforme un fichier en tableau (une ligne du fichier par élément du tableau).

• for ((k=0;k<${#FIC1[@]};k++))

  C'est une boucle, k variant de 0 à ${#FIC1[@]} - 1
  ${#FIC1[@]} est le nombre d'éléments du tableau FIC1.

Voici des extraits de man bash :

choix=$(for ((k=0;k<${#FIC1[@]};k++))

si ce n'est pas trop te demander.

choix=$(awk 'NR == FNR { ligne3[$0]=1; next } { getline ligne2 < "fichier2"; if (ligne3[ligne2]) print "TRUE"; else print "FALSE"; print $0; print ligne2 }' fichier3 fichier1) | zenity ...

Edit : rajout d'un ; avant le else. Je sais pas du c'est nécessaire... En fait, je sais meme pas si ça marche mon truc de toute manière !
Sur ce, bonne nuit à vous !

readarray -t FIC1 <fichier1
readarray -t FIC2 <fichier2

choix=$(for ((k=0;k<${#FIC1[@]};k++))
do
   grep -q "^${FIC2[$k]}$" fichier3 && echo true || echo false
   echo "${FIC1[$k]}"
   echo "${FIC2[$k]}"
done | zenity --list  --checklist --separator='\n'  --print-column=3 --width=800 --height=600 --title="Choix :" --column="choix :" --column="colonne1" --column "colonne2")

echo choix="$choix"

^ :       Le début de ligne
$lig2 : La variable contenant une ligne de fichier2
$ :       La fin de la ligne

La concordance n'est acceptée que si les 2 lignes sont identiques, et pas si "$lig2" est un morceau d'une ligne de fichier3.

Je crois bien que tu as tout compris. C'est pour ça que j'ai fais une 2ème boucle avec un fichier(.compare) contenant la liste des lignes à cocher (grâce à grep -f) pour lesquelles ajout="TRUE" mais je ne sais pas si je suis sur le bon chemin. En tout cas je n'arrives pas à l'intégrer au script.