[RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

Antoine P · Le 30/07/2012, à 22:24

Bonjour à tous,

Serait-il possible d'encadrer que quelques mots ou quelques lettres dans LibreOffice Writer et non tout un paragraphe ?

Merci d'avance.

Dernière modification par Antoine P (Le 03/08/2012, à 21:07)

Marcounnet · Le 30/07/2012, à 22:59

En faisant Insertion --> Cadre, cela devrait être possible, il faut bien mettre les bonnes caractéristiques par contre

Antoine P · Le 31/07/2012, à 07:19

J'ai déjà essayé mais c'est pas ce qu'il faut. Le cadre ne suis pas les caractères à encadrer. Ce serait bien que ce soit comme la fonction souligné

serged · Le 31/07/2012, à 07:33

C'est pas parfait, mais les effets "surlignage" + "soulignage" ça peut aider...

compte supprimé · Le 31/07/2012, à 08:42

Antoine P a écrit :

Bonjour à tous,
Serait-il possible d'encadrer que quelques mots ou quelques lettres dans LibreOffice Writer et non tout un paragraphe ?
Merci d'avance.

Salut !
Ce n'est pas encore possible, mais j'ai vu passer sur le planet de libreoffice, un billet d'un type qui travaille dessus.
Donc ça devrait arriver dans une prochaine release.

auzay · Le 01/08/2012, à 00:24

Bonjour

Parade sur une ligne : insérer un tableau 3 colonnes :avec colonnes extrémitées sans bordures colonne centrale avec bordure pour encadrer le mot ou les lettres .

Blek85 · Le 03/08/2012, à 17:13

Bonjour,

L'adresse d'un fichier à télécharger contenant une macro qui permet d'encadrer une sélection.
C'est pas tout neuf... Faut voir et tester bordure_selection_v1.sxw
Mais comme le disait si justement Marcounnet dans le post #2, c'est ni plus ni moins qu'un cadre de texte avec les propriétés adéquates, ancré comme caractère, etc.

Dernière modification par Blek85 (Le 03/08/2012, à 17:20)

Alain P · Le 03/08/2012, à 17:27

J'ai testé la macro et cela ne marche pas! Désolé

Blek85 · Le 03/08/2012, à 19:07

Effectivement, je me souviens maintenant avoir eu quelques soucis et je l'avais réécrite à ma façon.
J'espère que l'auteur ne m'en voudra pas si je la publie ici.

Attention ! Code remplacé à 20 heures.
Le précédent n'était pas la bonne version.

REM  *****  BASIC  *****
Option Explicit

'---------------------------------------------------------------------
' D'après une macro de : Agnès Simonet pêchée ici :
' http://www.openoffice.org/fr/Documentation/Macros/bordure_selection_v1.sxw
' Contributeur : Didier_Dorange-Pattoret
' pour l'accès aux tableaux et cadres.
' Contributeur : Bernard Marcelly  
' pour la solution au problème des fantômes dans les cadres.
' Le texte sélectionné ne doit pas contenir des sauts de ligne
' ou des sauts de paragraphe sinon bizarreries 
'---------------------------------------------------------------------
' Version revue par ADLC pour son usage perso
'---------------------------------------------------------------------
sub Bordure_Selection()
dim oDoc as object, oTexte as object 
dim oCurs as object, oCursVisible as object
dim oCadre as object, oCursCadre as object
dim tailleCadre as new com.sun.star.awt.Size
dim texteSelect as string
dim carFontName, carHeight, carWeight, carPosture
dim carUnderLine, carColor, carShadowed, carContoured, carRelief
dim justif as integer

	oDoc = ThisComponent
	oCursVisible = oDoc.currentcontroller.viewCursor
	oTexte = oCursVisible.text 
	oCurs = oTexte.createTextCursorByRange(oCursVisible)
	
	texteSelect = oCurs.string ' Texte sélectionné
	if len(texteSelect) = 0 then
		msgBox("Sélectionner d'abord un ou plusieurs mots.", _
			16, "### ERREUR SELECTION ###   ")
		exit sub 						' >>>>>>> SORTIE >>>>>>>		
	end if
	
	with oCurs
		carFontName	 = .charFontName
		carHeight	 = .charHeight
		carWeight	 = .charWeight
		carPosture	 = .charPosture
		carUnderLine = .charUnderLine
		carColor	 = .charColor
		carShadowed	 = .charShadowed
		carContoured = .charContoured
		carRelief	 = .charRelief
	end with
	
	oCadre = oDoc.createInstance("com.sun.star.drawing.TextShape")
	tailleCadre.width = 1
	tailleCadre.height = 1
	
	oTexte.insertTextContent(oCurs, oCadre, true)
	with oCadre
		.size = tailleCadre

		'ancrage comme caractère
		.anchorType = _
			com.sun.star.text.TextContentAnchorType.AS_CHARACTER

		'contour 
		.lineStyle = com.sun.star.drawing.LineStyle.SOLID

		.vertOrient = com.sun.star.text.VertOrientation.CHAR_CENTER

		.TextVerticalAdjust = _
			com.sun.star.drawing.TextVerticalAdjust.CENTER

		' adapter la taille du cadre à celle du texte
		.textAutoGrowWidth = true
		.textAutoGrowHeight = true
		
		oCursCadre = .text.createTextCursor
	end with
	
	with oCursCadre
		.charFontName	= carFontName
		.charHeight		= carHeight
		.charWeight		= carWeight
		.charPosture	= carPosture
		.charUnderLine	= carUnderLine
		.charColor		= carColor
		.charShadowed	= carShadowed
		.charContoured	= carContoured
		.charRelief		= carRelief
	end with
	
	oCadre.text.insertString(oCursCadre, texteSelect, true)

	oCadre.layerId = 1	' Cadre au premier plan

	' Forcer la rejustification du paragraphe
	justif = oCurs.paraAdjust
	if justif < 4 then
		oCurs.paraAdjust = justif + 1		
	else
		oCurs.paraAdjust = 0
	end if
	oCurs.paraAdjust = justif
end sub

Dernière modification par Blek85 (Le 03/08/2012, à 20:04)

Alain P · Le 03/08/2012, à 20:39

Ok merci pour la macro, reste à l'intégrer dans une macro Basic Libreoffice
Je teste et donnerai compte rendu
@+

Alain P · Le 03/08/2012, à 21:05

Je viens de tester en assignant la macro dans la barre d'outils et cela fonctionne laissant les caractères encadrés modifiables (couleurs attributs etc.)
L'on peu aussi donner au cadre d'autres attributs. C'est parfait pour ce que je vais en faire.
Merci encore à tous.
Si d'autres propositions se font elles seront étudiées avec attention.
Salutations

Antoine P · Le 03/08/2012, à 21:06

Merci, ça fonctionne …

alca94 · Le 04/08/2012, à 00:05

Bonsoir
C'est ce que je cherchais dans libre office depuis longtemps mais là je ne comprends pas comment l'integer ni après comment s'en servir
J'ai bien vu ça ,mais ça date et en plus j'ai rien compris .Si quelqu'un pouvait m'expliquer simplement (voir même très simplement,pas a pas )
http://user.services.openoffice.org/fr/ … 02&start=0
A l'avance Merci

Blek85 · Le 04/08/2012, à 08:27

Bonjour,

A Antoine P et Alain P : merci pour le retour. Ravi d'avoir pu vous aider.

A alca94 : Ce sujet, initié par Antoine P, est clos parce que [RÉSOLU] !
Votre question est tout autre et n'a en principe rien à faire à la suite de ce fil.
Pour savoir où placer une macro et comment l'utiliser, une piste parmi d'autres :
OpenOffice - How-Tos Programmation
Titre : Débuter - Description : Comment faire et utiliser des macros en basic

Dernière modification par Blek85 (Le 04/08/2012, à 08:33)

Ubuntu-fr

Navigation

Liens de recherche

Annonce

#1 Le 30/07/2012, à 22:24

[RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#2 Le 30/07/2012, à 22:59

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#3 Le 31/07/2012, à 07:19

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#4 Le 31/07/2012, à 07:33

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#5 Le 31/07/2012, à 08:42

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#6 Le 01/08/2012, à 00:24

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#7 Le 03/08/2012, à 17:13

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#8 Le 03/08/2012, à 17:27

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#9 Le 03/08/2012, à 19:07

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#10 Le 03/08/2012, à 20:39

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#11 Le 03/08/2012, à 21:05

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#12 Le 03/08/2012, à 21:06

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#13 Le 04/08/2012, à 00:05

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

#14 Le 04/08/2012, à 08:27

Re : [RÉSOLU] Encadrer un mot ou quelques lettres dans LibreOffice Writer

Pied de page des forums