Liste de Commandes/Fonctions utile sous VIM

Luc Hermitte · Le 15/04/2009, à 18:30

C'est fait pour. Dès que tu as un <plug>, c'est que le mainteneur du plugin a prévu le coup.

Chibie · Le 16/04/2009, à 08:16

sniff ! ... comme tu l'a fait remarqué, ça ne corrige pas l'histoire du [C] en tappant F3 ...

Dernière modification par Chibie (Le 16/04/2009, à 09:01)

Luc Hermitte · Le 16/04/2009, à 22:59

Ben non. Pour ça, il appliquer une des corrections que j'avais précédemment évoquées.
Le plugin de commentaire que tu vas utiliser ne vas rien y changer. C'est F3 qui est maudite.

Dernière modification par Luc Hermitte (Le 16/04/2009, à 22:59)

Chibie · Le 17/04/2009, à 13:54

J'ai pas encore trouver comme faire avec le F3 ou F4 mais bon ... sinon pour mon folding sur les {} j'ai trouvé.
Suffis de mettre set foldmarker={,} .... le truc tout simple mais suffisant.

Un autre truc que je sais pas trop où chercher via google :
J'ai une ligne en entête de fichier qui est comme suit :

#     REVISION:  17.04.2009 15:05:56                                                    #

J'aimerai que chaque fois que je ferme mon fichier il remplace la date et heure par celle de l'instant où je le ferme.

Je suis sûr d'avoir vu un truc du genre sur un site mais je ne le retrouve plus ... ...

Quelqu'un a une idée sur comment faire ça ?

Dernière modification par Chibie (Le 17/04/2009, à 14:09)

Luc Hermitte · Le 17/04/2009, à 14:18

Pour F3, relis mes précédents messages. J'ai déjà donné deux solutions (1- gvim, 2- fichier à charger depuis le vimrc)

Pour la seconde question, sur un BufWritePre, il faut faire une recherche de la ligne REVISION, et la remplacer. (utiliser un outil dédié (cvs, svn, git, ...) étant évidemment la solution à préférer).

Voici un exemple de script que j'avais pondu pour traquer des gens qui modifiaient violemment certains fichiers sans passer par les procédures en vigueur sur un projet:

" à déposer dans ~/.vim/plugin/trace_les_vilains.vim
if &cp == 1
  throw "Sorry you must launch vim and not vi"
endif

let s:cpo_save=&cpo
set cpo&vim
"------------------------------------------------------------------------

function! s:User()
  if exists('$USER') 
    return $USER
  else
    " matchstr utilisé pour faire un 'chomp'
    return matchstr(system('whoami'), "[^\r\n]*")
  endif
endfunction

function! s:LoggueLeVilain()
  " Avec :put, on fait un ajout
  let ligne = "Fichier modifié par ". s:User() ." à ".strftime('%c')
  if 0
    0put=ligne
  else
    " Pour remplacer la ligne, c'est setline(), et search pour la trouver
    " :h search()
    " :h setline()
    let ll = search( "Fichier modifié par ")
    if ll > 0
      call setline(ll, ligne)
    else
      0put=ligne
    endif
  endif
endfunction

aug TraquonsLesVilains
  au!
  " Ajouter les autres extensions à la liste
  au BufWritePre *.c,*.cpp,*.h,*.pl,*.ksh call s:LoggueLeVilain()
aug END

"------------------------------------------------------------------------
let &cpo=s:cpo_save

Je te laisse adapter ce code, ce n'est pas bien compliqué.

Chibie · Le 17/04/2009, à 14:25

Merci ... j'ai réussi à l'adapter et ça marche très bien (^_^)

Pour f3 j'ai tenté tes solutions mais ça ne donne rien ... ma touche est vraiment maudite ...

Luc Hermitte · Le 17/04/2009, à 14:45

Même avec gvim ?

Chibie · Le 17/04/2009, à 15:17

j'ai pas testé sur gvim car je souhaitais n'utiliser que vim ...

tshirtman · Le 17/04/2009, à 15:35

Moi non plus j'aime pas gvim ^^, même en virant tous les menus... c'est pas pareil ^^.

Luc Hermitte · Le 17/04/2009, à 15:53

Ouaip pas pareil. Sous l'un il n'y a pas de problèmes bizarres avec la gestion du clavier...
Sinon, pour le fichier que j'avais donné, il faut le sourcer depuis le vimrc, mais ne copie-colle pas son contenu, il y a des codes particuliers dedans, sauves-le plutôt sur ton disque avant de manipuler son contenu.

Chibie · Le 17/04/2009, à 16:33

Bon ok ma touche est vraiment maudite elle ne marche pas non plus sous gvim.

Luc Hermitte · Le 17/04/2009, à 16:41

Là, cela sent d'autres problèmes de configuration, et un fil de discussion non réservé à vim serait peut-être plus approprié.

chimay · Le 17/04/2009, à 19:28

salut les vimeurs avertis, merci à tous pour vos astuces, voici mon vimrc si ça peut aider quelqu'un :

" ------------------------------------------------------------------------
"  Générique
" ------------------------------------------------------------------------

set nocompatible			" Ne pas assurer la compatibilité avec l'ancien Vi
set iskeyword+=_,$,@,%,#	" Clefs
set autoread				" Recharge automatique des fichiers

" ------------------------------------------------------------------------
"  Historique
" ------------------------------------------------------------------------

set history=1284	" Nombre de commandes dans l'historique
set undolevels=120	" Nombres d'annulations possibles

" ------------------------------------------------------------------------
"  Encodage
" ------------------------------------------------------------------------

set encoding=utf-8
setglobal fileencoding=utf-8

" ------------------------------------------------------------------------
"  Écran
" ------------------------------------------------------------------------

syntax on			" Active la coloration syntaxique
set number			" Numérotation des lignes
set showmatch		" Affiche la paire de parenthèses
set matchtime=7		" Fréquence de showmatch
set scrolloff=2		" Minimum de lignes visibles à l'écran au-dessus
					" 		du curseur
set sidescrolloff=2
set linespace=0		" Espacement des lignes
set nostartofline	" Essaye de garder le curseur dans la même colonne quand
					" 		on change de ligne

set ruler			" Affiche la position du curseur ligne,colonne
set laststatus=2	" Affiche une barre de status en bas de l'écran
set showcmd			" Affiche les commandes dans la barre de statut
set cmdheight=1		" Hauteur de la barre de commande

" Contenu de la barre de statut

set statusline=%<%f%m\ %a\ [%1*%M%*%n%R%H]\ %r\ %h\ %w\ %P%=%-19(%l,%c%V%)\ %L\ \ \ %{strftime('%H:%M')}\ \ %O'%02b'

" ------------------------------------------------------------------------
"  Clavier
" ------------------------------------------------------------------------

set backspace=2			" Active la touche Backspace
set whichwrap=<,>,[,]	" Autorise le passage d'une ligne à l'autre avec les flèches

" ------------------------------------------------------------------------
"  Souris
" ------------------------------------------------------------------------

set mouse=a				" Utilise la souris partout
set mousehide			" Cache le pointeur de souris lorsque l'on tape
set mousem=extend
" set selectmode=mouse	" Sélection à la souris

" ------------------------------------------------------------------------
"  Thèmes
" ------------------------------------------------------------------------

set background=dark
" set background=light

" colorscheme blue
" colorscheme darkblue
" colorscheme default
" colorscheme delek
" colorscheme desert
colorscheme elflord
" colorscheme evening
" colorscheme koehler
" colorscheme morning
" colorscheme murphy
" colorscheme pablo
" colorscheme peachpuff
" colorscheme ron
" colorscheme shine
" colorscheme slate
" colorscheme torte
" colorscheme zellner

" ------------------------------------------------------------------------
"  Recherche
" ------------------------------------------------------------------------

set incsearch	" Commence la recherche au fur et a mesure que l'on tape l'expression
set hlsearch	" Illumine les occurences de la recherche
set ignorecase	" Ignore la casse
set smartcase	" Recherche intelligente : ignore la casse sauf si
				"		des majuscules sont présentes dans le motif

" ------------------------------------------------------------------------
"  Complétion
" ------------------------------------------------------------------------

set wildmenu
set wildmode=list:full

" ------------------------------------------------------------------------
"  Indentation
" ------------------------------------------------------------------------

set noautoindent	" Ne garde pas l'indentation de la ligne précédente
					" 		quand on commence une nouvelle ligne
set tabstop=4		" Largeur d'une tabulation
set shiftwidth=4

" ------------------------------------------------------------------------
"  Arborescence
" ------------------------------------------------------------------------

set foldmethod=indent	" Le découpage des folders se base sur l'indentation
" set foldmethod=manual
set foldlevel=12		" Nombre de niveaux
set foldcolumn=3		" Nombre de colonnes pour afficher l'arborescence

" ------------------------------------------------------------------------
"  Divers
" ------------------------------------------------------------------------

set nojoinspaces

" ------------------------------------------------------------------------
"  Abréviations
" ------------------------------------------------------------------------

ab totu tout

" ------------------------------------------------------------------------
"  Maps
" ------------------------------------------------------------------------

" Permet le shift-insert fonctionnel comme dans les Xterm

map <S-Insert> <MiddleMouse>
map! <S-Insert> <MiddleMouse>

" Correction orthographique

map § :w<cr>:!aspell -c %<cr>:e %<cr>

" Ctrl <-- -->

inoremap <C-Left> <C-o>b
inoremap <C-Right> <C-o>w

" Onglets

noremap <C-Insert> :tabnew<cr>
noremap <C-Del> :tabclose<cr>
noremap <M-PageUp> gT
noremap <M-PageDown> gt

" Ouvre un fichier d'après le nom

map gF :sp<cr>gf

" Tableau HTML

inoremap _tabhtml <table><cr><tr><cr><tab><td></td><cr></tr><cr></table>

" Fonction main C

inoremap _main int main (int argc, char *argv[])<cr>{<cr>return 0;<cr>}<esc>2ko

" Commentaires

vmap <F3> :s:^:\# :<cr>
vmap <F4> :s:^\( *\)\# :\1:e<cr>

" Wrappe à 72 caractères

" map F2 {v}! par 72

" Wrappe et justifie à 72 caractères

" map F3 {v}! par 72j

" ------------------------------------------------------------------------
"  Auto-commandes
" ------------------------------------------------------------------------

au BufWrite * silent! %s/[\r \t]\+$//	" Supprime les espaces en fin
										" 		de ligne avant de sauver
au BufEnter * lcd %:p:h					" Change le répertoire courant
										" 		vers celui du fichier ouvert

" ------------------------------------------------------------------------
"  Lilypond
" ------------------------------------------------------------------------

set runtimepath+=/usr/share/lilypond/2.10.33/vim/

" ------------------------------------------------------------------------
"  Mutt
" ------------------------------------------------------------------------

au BufNewfile,BufEnter,BufRead ~/etc/courriel/mutt/tmp* so ~/etc/courriel/vimrc.mutt

Dernière modification par chimay (Le 21/04/2009, à 23:05)

Vigor · Le 21/04/2009, à 16:34

Bonjour a tous.

J'ai commencer a me pencher sur vim mais je rencontre quelques problemes lors de sa configuration:

D'abord je n'arrive pas a désigner le registre systeme pour copier/coller/couper, quand j'essaye de "*p ou "+p (je ne sais pas laquelle est vraiment la bonne commande, j'ai trouver ces deux versions sur le net) rien ne se passe, j'ai set le showcmd et quand j'appuie sur + ou * sa me reset la commande (* me renvoi vers la prochaine occurence du mot sous le curseur). Idem lors de la copie. C'est assez embetant car je ne peux rien récuperer et suis toujours obliger de tout retaper. La seule solution que j'ai pu trouvé est le clic droit, coller mais bon je souhaire utiliser vim pour m'affranchir de la souris.

Ensuite j'ai un probleme de mapping, je souhaite mapper l'autocompletion en ctrl+space au lieu du ctrl+x ctrl+o (en insertion) mais sa ne marche pas :

inoremap <c-space> <c-o><c-x>

j'ai essayer avec map et imap aussi, et le mapping apparait bien dans le :map! mais quand j'essaye d'utiliser ce raccourci sa ne produit pas l'effet voulu, il quitte l'insertion (et encore quand il ne colle pas un truc sorti de je ne sais ou) et ne m'affiche pas le wildmenu comme quand je tape ctrl+x ctrl+o. Je ne comprend pas pourquoi ce mapping ne marche pas alors que d'autre fonctionnent très bien (comme ceux trouvés ici meme).

J'ai installer eclimd que je n'ai pas reussis a faire marcher correctement pour l'autocompletion alors j'ai pris un plugin omnicomplete (c'est lui que je cherche a mapper sur ctrl+space) qui marche, finalement je n'utilise pas eclimd et souhaite le désinstaller mais j'ai peur de tout casser, comment l'enlever proprement?

Je tourne sous ubuntu 8.10 avec vim (pas g) avec ce .vimrc :

"base
syn on
set syntax =on
filetype indent plugin on
set nocp
set nu
set mouse =a
set showmatch
set incsearch
set ignorecase
set smartcase

"menu list
set wildmenu
set wildmode =list:longest,list:full
set wildignore =*.o,*.r,*.so,*.sl,*.tar,*.tgz

"param fold
function! FoldFuction()
	let line = getline(v:foldstart)
	let sub = substitute(line,'/\*\|\*/\|^\s+', '', 'g')
	let lines = v:foldend - v:foldstart +1
	return v:folddashes.sub.'...'.lines.' lignes'.getline(v:foldend)
endfunction

set foldmethod =syntax
set foldtext =foldFuction()

"dico ortho
set spelllang =en,fr
set spell
set spellsuggest =5

set cursorline

iab sysout System.out.println();
colorscheme couleur

helptags $HOME/.vim/doc/

"only do this part when compiled with support for autocommands
if has("autocmd")
	autocmd Filetype java setlocal omnifunc=javacomplete#Complete
endif

set showcmd
iab mainclass public void main(String[] args){<CR><CR><CR>}<ESC>3k
inoremap <buffer> <C-Space><C-X><C-O>

inoremap "" ""<esc>i
inoremap '' ''<esc>i
inoremap (( ()<esc>i
inoremap [[ []<esc>i
inoremap {{ {}<esc>i
inoremap {<CR> {<CR>}<esc>O<tab>

Mon vimrc est un peu sale encore mais je n'en suis qu'au début donc si vous trouvez des améliorations a apporter ce n'est pas de refus
Ma finalité est de laisser tomber eclipse pour ne developper que sur vim.

En vous remerciant

Luc Hermitte · Le 21/04/2009, à 17:04

<c-space> ne se mappe pas partout -- je n'ai jamais eu de problèmes sous gvim, mais impossible d'y arriver sous vim via exceed. Pour voir si tu le supportes, tape <c-v><c-space> (en 2 paires de touches) en mode commande.

<buffer>, c'est pour les mappings/abbréviations locaux à un buffer. Hors .le vimrc ne peut contenir que des définitions globales -- sinon elles seront ignorées dans les autres buffers. Autrement dit, <buffer> sera utilisé dans les ftplugin (et autres mappings que l'on charge sur des autocommands).

Pour les mappings sur les paires de parenthèses, on peut faire beaucoup mieux -- mais je ne suis pas objectif, vu que je maintiens la suite évoluée la plus ancienne sur le sujet.

Pour copier, il faut bien évidemment taper le guillemet qui sert à introduire le registre de destination (+ ou * dans ton cas), et cela ne marchera qu'en modes normal ou visuel. Tu pourras vérifier leur contenu avec un :echo @+ ou :echo @*. Mais étant sous un *nix, autant juste sélectionner et copier ailleurs avec un simple clic milieu. [il y a peut-être une ou deux options à régler pour cela]

helptags n'a rien à faire dans le .vimrc. C'est une commande que l'on exécute ponctuellement quand on installe des nouveaux *-plugins qui ne sont pas packagés dans des vimball.

Pour désinstaller un plugin, s'il est venu dans un vimball, lis la doc à ce sujet (:h vimball), sinon repère tous les fichiers que ton archive contient, et supprime les un à un -- ou avec cat + xargs + rm si tu sais t'en servir.

fredr · Le 21/04/2009, à 18:10

Salut,

Un peu de doc: http://www.mumblyworld.info/?p=218

Pour le registre:

:reg t'affiche les registres existants et "4p te colle le 4° registre.

Fred

chimay · Le 21/04/2009, à 23:14

Juste une petite remarque, apparemment :

"*p est équivalent au clic milieu
"+p est équivalent à Ctrl-v

Vigor · Le 22/04/2009, à 09:12

Tout d'abord merci pour vos réponses.

Lorsque je fais le <c-v><c-space> (en mode insertion en normal rien ne se passe) il m'envoi ^@ comme caractère. Est ce le bon?

Pour le mapping des parenthèses j'ai repris le vimrc de Chible (donné sur ce topic).

Pour le copier/coller je n'arrive pas a désigner le registre systeme que ce soit avec "+p ou "*p et quand j'affiche les buffers avec un :reg ils n'apparaissent pas, rien ne se passe aussi quand je fais :echo @+ ou :echo @*. Le clic milieu colle et je ne peux pas copiez en séléctionnant manuellement, juste coller. J'utilise un gestionnaire de presse papier, glipper, cela pourrait venir de la? Si non d'ou peut venir ce problème?

Le helptags m'indique les pages en francais, l'anglais ne me dérange pas mais pour certaines notions obscures c'est parfois difficile a comprendre donc j'ai récupere la doc en francais. Meme dans ce cas doit il se trouver ici? si non ou dois je le mettre?

Je ne connais pas les vimballs, j'ai vu que c'etait un plugin qui facilite la gestion des plugins, existe il des sites qui liste les vimballs?

Je souhaite faire de vim un ide java principalement, j'ai deja mis un plugin compile/run et une omnicompletion (qu'il me reste a mapper correctement), quel sont les plugins dont j'aurais besoin ou qui me seront utiles?

Finalement ai je interet a passer a gvim? qu'apporte-t-il de plus? Peut on l'installer en meme temps que vim?

edit: j'ai remarquer lorsque je fais une update-alternatives --config editor j'ai vim.tiny et vim.basic d'installer. Ce sont bien les bons? Comment enlever le vim.tiny? J'ai installer vim avec apt-get.

Dernière modification par Vigor (Le 22/04/2009, à 09:45)

Luc Hermitte · Le 22/04/2009, à 10:40

Pour le ^@ affiché au lieu de <c-space>, j'ai peur que cela soit lié à ton terminal, et ça je ne sais pas faire. C'est un problème similaire à celui de chibie (?), et c'est une des raisons qui fait que j'utilise exclusivement gvim : toutes les touches sont correctement supportées -- ou en tout cas, bien mieux.

Pour le "+p. Il faudrait vérifier si :nmap " te renvoie quelque chose. Pour la souris, j'ai un ":behave xterm" des fois que cela change quelque chose.

:helptags est une commande qui s'utilise ponctuellement. C'est à dire : une seule fois. Voire une fois après chaque installation manuelle de plugin. C'est pour cela qu'elle n'a aucun sens dans le .vimrc.

Pour les vimballs (sortes d'archives auto-installables avec un :source), elles se trouvent pratiquement toutes sur vim.org. Ce qui ne m'empêche pas de laisser certaines des miennes sur mon site uniquement.

Des plugins encapsulant ctags peuvent t'être utiles. EnhancedCommentify/NerdCommenter (?) aussi. Un expander de templates/snippets. Un truc pour te générer la javadoc de tes fonctions. Un plugin de refactoring. Un truc pour compiler en tâche de fond depuis vim. Eventuellement de quoi positionner des options par projet.
Toutes ces choses, c'est ce que j'utilise, et j'en maintiens certaines en fait, mais pour le C++. Certaines de mes extensions devraient être facilement adaptables au Java, d'autres demanderont plus de boulot, et d'autres n'auront pas de sens en Java. Et peut-être que certaines ont déjà été faites par d'autres pour le Java -- je sais juste que je suis le seul à proposer une solution qui décode entièrement les signatures des fonctions C++ pour générer diverses choses à partir de là.

Côté installation, je laisse à d'autres le loisir de te répondre vu qu'en général je compile vim moi-même à partir des sources.

Chibie · Le 22/04/2009, à 14:13

Finalement je me suis dépatouillée autrement avec d'autre touche clavier.

Je voulais savoir si c'était possible d'insérer dans un document des lignes préformatées ... genre j'aimerai mettre avant chaque fonction d'un script :

=head2 fonction ma_fonction

 Title        : ma_fonction
 Usage        : my $res = &ma_fonction ( $arg );
 Prerequisite : none
            etc ..
=cut

Si vous avez des astuces ?

Dernière modification par Chibie (Le 22/04/2009, à 14:13)

Luc Hermitte · Le 22/04/2009, à 14:18

Oui, avec un plugin d'expansion de templates/fichiers squelettes/....

Il en existe une Ribambelle (sans parler des astuces du pauvre pour faire la même chose sans la notion de variables automatiquement remplacées)
Et je maintiens le mien

Vigor · Le 22/04/2009, à 17:35

Je suis finalement passer sous gvim.
Le presse papier fonctionne correctement mais le mappage de <c-space> toujours pas et lors du <c-v><c-space> n'affiche rien.

Je souhaite aussi enlever les menus et toolbar mais le :unmenu * ne marche pas. Je cherche a rendre gvim aussi minimal que vim. Ai-je manquer quelque chose? Y a t il des choses particulieres a savoir sur gvim par rapport a vim? (subtilité dans le .vimrc notamment)

@Luc Hermitte: merci pour tes réponses completes, la liste de plugins que tu m'a donné est complete mais finalement je l'etudierai plus tard. Je prefere m'excercer avec gvim actuel et le configurer comme il faut deja avant d'ajouter des plugins et me noyer dans les commandes.

Cordialement

Luc Hermitte · Le 22/04/2009, à 17:46

:h menu.vim
-> rajoute ce qui suit dans ton .vimrc ":let did_install_default_menus = 1"

Sinon, :h gui pour voir tout ce qui est spécifique à gvim.

Pour le coup du <c-space>, là, je sèche du coup. Je ne saurais pas te dire ce qu'il faut changer pour que cela fonctionne.

Tentez la ML anglophone pour vos questions de terminaux.

Vigor · Le 23/04/2009, à 08:17

J'ai deja mis cette ligne "let did_install_default_menus = 1" et elle n'a aucun effet.
J'ai deja regarder dans :h mais comme sa ne fonctionnais pas je me suis tourner vers vous.

Pour le <c-space> je vais me débrouiller ou au pire je mettrai l'autocompletion en tab.
edit: j'ai remarquer qu'au lancement de gvim il m'indique "aucun mappage trouvé" et quand je commente le mappage du <c-space> l'alerte disparais. Pourquoi sa ne le fais que pour ce mappage?

Merci encore

Cordialement

Dernière modification par Vigor (Le 23/04/2009, à 11:09)

Chibie · Le 23/04/2009, à 15:51

Dis moi Luc, je suis partie pour utiliser snippets.vim qui semble assez simple. Seule problème je trouve que ça manque totalement de documentations et quand tu chercher sur google tu as de tout et rien, bref je me perd.
Tu as un tuto qui explique comment faire nos fichiers snippet correctement ?

PS : Je ne parle pas du template que tu charge à l'ouverture de fichier avec une extension spécifique, ça c'est bon je l'ai fait Et par contre tu as pleins de site qui l'explique ça, contrairement à l'autre ! (-_-)"
Je parle de morceaux de code à insérer en cours de frappe (mode i) par exemple ou dans la ligne courante (mode v/n). Merci !

Dernière modification par Chibie (Le 23/04/2009, à 15:52)

Ubuntu-fr

Navigation

Liens de recherche

Annonce

#251 Le 15/04/2009, à 18:30

Re : Liste de Commandes/Fonctions utile sous VIM

#252 Le 16/04/2009, à 08:16

Re : Liste de Commandes/Fonctions utile sous VIM

#253 Le 16/04/2009, à 22:59

Re : Liste de Commandes/Fonctions utile sous VIM

#254 Le 17/04/2009, à 13:54

Re : Liste de Commandes/Fonctions utile sous VIM

#255 Le 17/04/2009, à 14:18

Re : Liste de Commandes/Fonctions utile sous VIM

#256 Le 17/04/2009, à 14:25

Re : Liste de Commandes/Fonctions utile sous VIM

#257 Le 17/04/2009, à 14:45

Re : Liste de Commandes/Fonctions utile sous VIM

#258 Le 17/04/2009, à 15:17

Re : Liste de Commandes/Fonctions utile sous VIM

#259 Le 17/04/2009, à 15:35

Re : Liste de Commandes/Fonctions utile sous VIM

#260 Le 17/04/2009, à 15:53

Re : Liste de Commandes/Fonctions utile sous VIM

#261 Le 17/04/2009, à 16:33

Re : Liste de Commandes/Fonctions utile sous VIM

#262 Le 17/04/2009, à 16:41

Re : Liste de Commandes/Fonctions utile sous VIM

#263 Le 17/04/2009, à 19:28

Re : Liste de Commandes/Fonctions utile sous VIM

#264 Le 21/04/2009, à 16:34

Re : Liste de Commandes/Fonctions utile sous VIM

#265 Le 21/04/2009, à 17:04

Re : Liste de Commandes/Fonctions utile sous VIM

#266 Le 21/04/2009, à 18:10

Re : Liste de Commandes/Fonctions utile sous VIM

#267 Le 21/04/2009, à 23:14

Re : Liste de Commandes/Fonctions utile sous VIM

#268 Le 22/04/2009, à 09:12

Re : Liste de Commandes/Fonctions utile sous VIM

#269 Le 22/04/2009, à 10:40

Re : Liste de Commandes/Fonctions utile sous VIM

#270 Le 22/04/2009, à 14:13

Re : Liste de Commandes/Fonctions utile sous VIM

#271 Le 22/04/2009, à 14:18

Re : Liste de Commandes/Fonctions utile sous VIM

#272 Le 22/04/2009, à 17:35

Re : Liste de Commandes/Fonctions utile sous VIM

#273 Le 22/04/2009, à 17:46

Re : Liste de Commandes/Fonctions utile sous VIM

#274 Le 23/04/2009, à 08:17

Re : Liste de Commandes/Fonctions utile sous VIM

#275 Le 23/04/2009, à 15:51

Re : Liste de Commandes/Fonctions utile sous VIM

Pied de page des forums