Ubuntu-fr

silver74

besoin d'aide pour adapter une macro excel pour OO-calc

Bonjour,

je doit faire un planning avec 20 personnes et chaque personne doit etre écrit avec une couleur différente.Je veut dire quand j'écris paul dans une cellule,paul va etre écris en vert.Quand jécris pierre,bah pierre va etre en bleu.

Je reussi le faire avec les conditions optionelles et les styles,mais dans les conditions il ya que 3 possible.Mais comme il me faut 20,je voudrais savoir si avec une macro ca serrait possible.Parcontre je ne connais rien en macro, a la rigueur je peut faire un sandwich au thon.

Donc si qq1 peut m'aider svp ça serrait gentil.

merci d'avance

PS.:Je changer le titre,car je trouvé ce que je voulais,mais malheureusement que pour excel.

Dernière modification par silver74 (Le 28/10/2007, à 00:54)

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

JBF

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Bonsoir,

tu devrais pouvoir te tirer d'affaire sans macro en utilisant la fonction STYLE comme expliqué dans l'aide en ligne (Voir STYLE, exemple de fonction). Cependant pour 20 couleurs différentes ça risque d'être assez fastidieux à écrire avec des IF (ou Si in French) emboîtés.

Je te conseille le site suivant qui est une mine pour l'utilisation de OOo-Calc : http://christianwtd.free.fr/
Pour STYLE() il y a des exemples ici : http://christianwtd.free.fr/index.php?r … #FnSTYLEex

JBF

---

LibreOffice : https://fr.libreoffice.org/ (téléchargement, documentation, FAQ, assistance, contribuer, ...)
Aide pour LibreOffice par la communauté francophone : https://ask.libreoffice.org/fr/

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Je deja reflechis pour les styles,mais le probleme ca va etre horrible de pour le modifier apres.Donc je pense une macro ca serrait le plus simple.Je trouvé 1-2 macros pour office2003,mais malheuresement ca ne marche pas sous openoffice.

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Bon grace a un autre site je reuissi faire un model sous excel,mais il serai trop beau si il marcherai aussi sous openoffice 2.3.
Donc si qq1 dans cette forum à la gentillesse de m'aider pour l'adapter po opoenoffice.

Voila le fameux fichier:

planning_couleur.xls (43 ko)

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

personne peut m'aider ?

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

Kéral

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Bonsoir,

Je crois que tu as de la chance car je travail sur le même sujet en ce moment.

Je t'ai adapté ton fichier pour OpenOffice, mais j'ai fait une macro pour pouvoir faire les 14 couleurs.

J'ai modifié ton DATA pour y ajouter une cellule qui comptabilise le nombre de personne et une colonne pour affecter un n° de couleur qui ce trouve dans la macro.

Le fichier est téléchargeable à cette adresse
http://espace.virtuel.free.fr/temp/temp.zip

Pour que ma solution puisse servir à ceux qui passeront par ce post, je met le code utilisé pour la macro  !

Il y a certainement moyen de l'optimiser, mais je laisse cela à ceux qui voudront ce lancer dans l'aventure !

Option Explicit
Dim oMonClasseur as variant, oFeuille1 as variant,  oFeuille2 as variant, oCellule1 as variant


sub ColorePersonnel
	Dim oCellule2 as variant
	Dim oNbColonne as integer, oNbLigne as integer, oCompteur as integer, oNbPersonne as integer
	Dim oCol as integer, oLign as integer
	Dim oLaCouleur as variant, oPersPlanning as string, oPesonnel as string
	
	oMonClasseur = ThisComponent
	Rem Feuille planning
	oFeuille1 = oMonClasseur.Sheets.getByName("planning")
	Rem Feuille DATA
	oFeuille2 = oMonClasseur.Sheets.getByName("DATA")
	
	Rem Récupération du nombre de personne dans DATA
	oNbPersonne = oFeuille2.getcellrangebyname("C2").value
	
	Rem Nombre de colonne à explorer sans la première
	' A modifier en cas d'ajout ou de suppression de colonne
	oNbColonne = 7
	Rem Nombre de ligne à explorer sans la première
	' A modifier en cas d'ajout ou de suppression de ligne
	oNbLigne = 43
			
	
	Rem On passe au crible les valeurs des cellules du planning et on les compares avec les noms pour leur affecter une couleur
	for oCol = 1 to oNbColonne
		for oLign = 1 to oNbLigne
			Rem On récupère les valeurs des cellules dans la feuille planning
			oCellule1 = oFeuille1.getCellByPosition(oCol, oLign).string
			oPersPlanning = oCellule1
			
                        REM SI oCellule1 DIFFERENT de vide ALORS
			if oCellule1 <> "" Then
				Rem On cherche le nom de la personne dans DATA 
				for oCompteur = 2 to oNbPersonne + 1
					Rem On passe la liste en revue pour comparer avec le contenu du planning
					oCellule2 = oFeuille2.getcellrangebyname("A" & oCompteur).string
					oPesonnel = oCellule2
					
					Rem SI le nom de la personne sur le planning identique à la liste 
					' ALORS on décal pour récupérer la couleur ou la mise en forme
					if StrComp(oPersPlanning, oPesonnel , 1) = 0 Then
					'	msgbox(oCellule1 & " sur " & oCellule2)
						Rem On récupère la couleur
						oLaCouleur  = oFeuille2.getcellrangebyname("B" & oCompteur).string
					
						Rem On appel la routine ChangeCouleur()
						call ChangeCouleur(oLaCouleur, oCol, oLign)
						'On quitte la boucle
						exit for
					endif
				Next oCompteur
			EndIf
		Next oLign				
	Next oCol
end sub


sub ChangeCouleur(LaCouleur, col, lign)

	Rem appel de la cellule du planning pour affectation de la couleur
	oCellule1 = oFeuille1.getCellByPosition(col, lign)
	
	Select Case LaCouleur
      Case "1"
      	'Couleur VERT CLAIR
        oCellule1.CellBackColor = RGB(35,255,35)
      Case "2"
        ' Couleur Violet
         oCellule1.CellBackColor = RGB(153,153,255)  
      Case "3"
           	msgBox("Couleur 3 non défini")
      Case "4"
        'Couleur Jaune
        oCellule1.CellBackColor = RGB(255,255,0)   
      Case "5"
        'Couleur Bleu
        oCellule1.CellBackColor = RGB(0,71,255)
      Case "6"
      		'Couleur Orange2
         	oCellule1.CellBackColor = RGB(255,102,51)
       case "7"
       		msgBox("Couleur 7 non défini")
       case "8"
       		msgBox("Couleur 8 non défini")
       case "9"
       		'Couleur NOIR
       		oCellule1.CellBackColor = RGB(0, 0, 0)
       case "10"
       		msgBox("Couleur 10 non défini")
       case "11"
       		msgBox("Couleur 11 non défini")
       case "12"
       		' Couleur Violet
         	oCellule1.CellBackColor = RGB(120,153,155)
	End Select 

	Rem Pour ajouter une couleur ajouter un ligne comme ci-dessous
	' Mettre le nom de la couleur (penser à le faire aussi dans DATA à côté du nom de la personne)
	' et l'équivalence en RVB
     ' case "11" et ainsi de suite....
     '   oCellule1.CellBackColor = RGB(XX, XX, XX)	
     
    
    REM *******************************************************
    ' POSSICBILITE DE METTRE EN FORME AVEC FORMATAGE POLICE  **
    '**********************************************************
    REM EXEMPLE
 '  case "1"
' 	 With oCellule1
		'insére du texte dans la cellule
'		.setString(HeureDepart+oLign-1 & "H-" & HeureDepart + oLign & "H")
		'indique la couleur de fond de la cellule
	'  	.CellBackColor = RGB(0,0,0) d
		'alignement centré
'		.paraAdjust = com.sun.star.style.ParagraphAdjust.CENTER 
	 ' 	.RotateAngle = 9000 'Rotation 9000 = 90°
	'couleur des caractères
'		.CharColor = RGB(255,0,0) 
		'Taille catactères
'		.CharHeight = 12 
		'gras
'		.CharWeight = com.sun.star.awt.FontWeight.BOLD 
		'italique
'		.CharPosture = com.sun.star.awt.FontSlant.ITALIC 
		' Type de la police
'		.CharFontName = "Arial" 
		'souligné double
		'  	.CharUnderline = com.sun.star.awt.FontUnderline.DOUBLE 
'	End With
'	case "2"
'		Idem ci-dessus
'	End Select
    
    
End Sub

Dernière modification par Kéral (Le 06/11/2007, à 11:38)

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Merci Kéral,ca marche ce presque parfait.Trop cool:D

Peut tu me dire comment changer le coloriage en couleur de texte, au lieu un coloriage de fond de cellule.Pour l'impression ca va couter bonbons.Car il faut l'imprimer pour chaque membre du planning,même si en fait une photocop en n&b ca va pas etre trop lisible.

Peur tu me dire aussi comment agrandir le bouton "actualiser le couleurs" et comment changer le texte?

merci bcp encore pour ton aide

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

Kéral

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Content que cela te plaise !

J'ai étais débutant un jours aussi et j'étais bien content d'avoir de l'aide et des explications !

Pour info, attention au respect de la case quand tu saisis le nom des employés, car je ne l'ai pas gérer, donc si tu écris Tonton dans DATA et que dans ton planning tu saisis tonton, il restera sans couleur.

Pour changer la mise en forme des cellules, il faut modifier la macro dans la routine
sub ChangeCouleur(LaCouleur, col, lign).
Tu changes le contenu des CASE par la mise en couleur du texte ou autres options que j'ai pris la peine de mettre en commentaire à la fin de la macro.

Exemple pour ajouter les options:

Select Case LaCouleur
      Case "1"
      	With oCellule1
	      	'Couleur de la cellule = VERT CLAIR
	        .CellBackColor = RGB(35,255,35)
	    	'couleur de la police de caractères
			.CharColor = RGB(255,102,51)
			'Taille de la police
   			.CharHeight = 10 
   			Rem les autres formatage (voir a la fin de la macro) etc...
	    End With
      Case "2"
      	With oCellule1
	      	' Couleur de la cellule = Violet
         	oCellule1.CellBackColor = RGB(153,153,255) 
	    	'couleur de la police de caractères
			.CharColor = RGB(35,255,35)
			'Taille de la police
   			.CharHeight = 10 
   			Rem les autres formatage (voir a la fin de la macro) etc...
	    End With
' Ainsi de suite ....

I.  et pour répondre à ta question tu ne met que la couleur de la police pour chaque personne, comme ci-dessous

Select Case LaCouleur
      Case "1"
      	With oCellule1
	    	'couleur de la police de caractères
			.CharColor = RGB(255,102,51)
   			Rem les autres formatage (voir a la fin de la macro) etc...
	    End With
      Case "2"
      	With oCellule1
	    	'couleur de la police de caractères
			.CharColor = RGB(35,255,35)
   			Rem les autres formatage (voir a la fin de la macro) etc...
	    End With
      Case "3" 
Rem Idem pour tous les CASE avec leur couleurs respectives

Comment Modifier une macro

1. Barre de menu de Calc aller dans Outils/Macros/Gérer les macros/OpenOffice.org Basic...  Cliquer

2. Une fenêtre s'affiche. Chercher le nom du fichier concerné, déployer son arborescence. NomFichier/Standart/Module1

3. Cliquer sur Module1 et à droite le nom des macros apparaissent. Sélectionner la macro ChangeCouleur et cliquer sur Editer dans les boutons de droite.

La fenêtre d'OpenOffice Basic s'ouvre

Vous pouver modifier votre code !

II. Modification du bouton.

Dans Calc il faut afficher la barre d'outils Contrôle des formulaires.

Procédure de modification du bouton :
1. Dans la barre de menu cliquer sur Affichage/Barre d'outils/Contrôle des formulaires
2. Cliquer sur le mode Conception (généralement le 2ème à côté de la flèche)
3. Cliquer sur le bouton et là tu peux le redimmensionner à la taille désirée ou le déplacer !
Changer le texte du bouton
    1.a En mode Conception, faire clique droit sur le bouton.
    1.b Tu clique sur Controle
    1.c Dans l'onglet Général, tu changes le texte du titre (2ème ligne)
    1.d Tu peux aussi tester les autres options pour découvrir !

4. Une fois l'opération terminé, cliquer à nouveau sur le mode Conception pour pouvoir utiliser le bouton !

Voilà j'espère qu'avec ces explications tu arriveras à trouver ton bonheur !

Bonne continuation dans tes réalisations !

P.S Les sites cités par JBF plus haut sont de très bon site pour apprendre !
A utiliser sans modération !

Dernière modification par Kéral (Le 06/11/2007, à 15:07)

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

D'abord un grand grand merci encore,je reussi du premier coup grace a ton tuto de le modifier.

Mais il me reste encore une p'tit dernière questions,apres je t'embete plus....enfin je crois

Pour editer les couleurs,je vu c un code.

RGB(255,102,51)

avec quelle editeur je peut voir à koi ca corespond.Car mon cerveau à la matrix est en panne.

Dernière modification par silver74 (Le 06/11/2007, à 14:06)

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

PB68

Re : besoin d'aide pour adapter une macro excel pour OO-calc

RGB(255,102,51)

avec quelle editeur je peut voir à koi ca corespond.Car mon cerveau à la matrix est en panne.

Tu peux passer par OpenOffice Draw et Gimp parmi d'autres.

PB68

---

Si ça t'aide, ça me fait plaisir

Kéral

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Tu peux passer par OpenOffice Draw et Gimp parmi d'autres.

PB68

Effectivement on peut les récupérer par cette manière. Sinon il existe aussi des utilitaires gratuit pour les avoir comme eyedropper par exemple.

Sinon voici des sites qui te faciliterons la tâche !

http://www.alterlinks.fr/conversion-tab … one=77DD77

OU

http://www.alaide.com/outils_convertrgbhexa.php

Pour tous ceux qui s'intéresse aux macros voici le site de SUN en français sur la programmation de StarOffice8 basic http://docs.sun.com/app/docs/coll/1277.1?l=fr
Vous avez la possibilité de le télécharger ou de le consulter en ligne la documentation.
Site a conserver dans ses favoris 

Dernière modification par Kéral (Le 06/11/2007, à 15:06)

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

dans mon truc de base il ete bcp plus simple de modifier les couleurs,sauf il marchait pas sous oo-calc il marchais pas.

Mais il y a pas de moyen d'ajouter un bouton/zone/truc dans DATA qui change la couleur du code du macro pour il soit ensuite active pour le planning?
Par exemple je sélection une couleur dans C2 pour la numero couleur dans B1,donc quand je selectioner la couleur le script de la macro va etre modifier.

Je dis ca car pour ca reste le plus simple possible pour tlm,car ce ne pas que moi qui va travailler avecce planning et quand il faut changer les couleurs il faut aller dans le code.Donc pas tres pratique.

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

Kéral

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Mais si ya toujours moyen d'améliorer !

Si tu trouve cette façon pénible, alors tu peux définir des styles perso !

Explication :

1. Dans une feuille tu fais plusieurs styles dans des cellules, Couleurs de fond et de police différents.
2. Ensuite dans la barre de menu tu cliques Format/Styles et Formatage
3. La fenêtre des styles s'ouvre
4. Tu sélectionnes une cellule que tu viens de formater
5. Dans la fenêtre des styles tu cliques en haut à droite sur le bouton (Créer un style à partir ....) une petite feuille avec un + vert
6. tu nommes ton style, vert, rouge etc...
7. Tu fais toute tes couleurs de la même manière

Voici une bonne explication en image ! http://christianwtd.free.fr/index.php?r … FormatCond

Voilà tu à créer des styles facilement et tu modifies la macro qui appelera directement tes styles créés.

Voici une macro exemple qui va mettre en forme la cellule A2.
On saisi rouge ou vert dans la cellule I4 et la cellule A2 prendre le style un fois la macro lancé !

sub AppelStyleDefinit
	Dim oMonClasseur as variant, oFeuille as variant, oCellule as variant       

	Rem Le classeur
	oMonClasseur = ThisComponent
	Rem La feuille concernée
	oFeuille = oMonClasseur.Sheets.getByName("EmploiDuTemps")
	Rem La cellule cible (0,1) = cellule A2
	oCellule = oFeuille.getCellByPosition(0,1)
	
	' Récupération du nom du style dans la cellule I4
	select case oFeuille.getCellRangeByName("I4").string         
	  case "vert"
	     Rem Affectation du style crée
	     oCellule.CellStyle="Vert"
	  case "rouge"
	     Rem Affectation du style crée
	     oCellule.CellStyle="Rouge"
	  case else   
	      'Le test "Else" qui applique le style Standard
	      oCellule.CellStyle="Standard"   
	end select
end sub

Si ce principe te plait mieux, alors y a plus qu'à adapter le script précédent !

Tout est possible avec un peu de travail et de recherche !

Dernière modification par Kéral (Le 07/11/2007, à 16:13)

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Donc si je bien compris la macro va regarder le formatage De la cellule I4 pour le repoduire dans la cellule a2.Si ce ca ce encore mieux,car comme ca ta juste besoin modifier la cellule et hop cha change le reste.

Par contre je pige pas comment le faire, reconnaitre automatiquement le formatage.Car une fois je vais ecrire "tom" dans la celule A1 et le texte deviens vert et un autrefois quand je besoin ecrire "sacha" en bleu dans la cellule a1.Comment ca marche tout seul?

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"

Kéral

Re : besoin d'aide pour adapter une macro excel pour OO-calc

C'est presque ça, une fois l'ancienne macro modifier, à côté du nom des employés (colonne B) tu mettra la couleur (nom du style crée), et le principe et le même.
On clique sur le bouton pour appeler la macro pour mettre en forme les noms des employés dans la feuille planning !

Démarche

1. Créer tous les styles (Couleur du texte, ect...) et les nommer rouge si le texte et rouge etc...

Voici une bonne explication en image ! http://christianwtd.free.fr/index.php?r … FormatCond

2. Modifier les CASE dans la routine sub ChangeCouleur(LaCouleur, col, lign)
en appelant les styles au lieu de mettre en forme avec RGB(), etc...

Comme cela tu n'auras plus besoin d'aller dans le code, sauf si tu rajoutes une couleur dans le futur, il faudra l'ajouter à la suite des autres CASE !

Et pour modifier les styles, comme mettre en gras par exemple, tu feras comme pour la création de style, mais cette fois tu fera Actualiser le style....

Je viens de te refaire le fichier avec la macro modifiée.

http://espace.virtuel.free.fr/temp/Planning2.zip

Voici le nouveau code, rien de changé sauf pour la routine sub ChangeCouleur(LaCouleur, col, lign)

Option Explicit
Dim oMonClasseur as variant, oFeuille1 as variant,  oFeuille2 as variant, oCellule1 as variant


sub ColorePersonnel
	Dim oCellule2 as variant
	Dim oNbColonne as integer, oNbLigne as integer, oCompteur as integer, oNbPersonne as integer
	Dim oCol as integer, oLign as integer
	Dim oLaCouleur as variant, oPersPlanning as string, oPesonnel as string
	
	oMonClasseur = ThisComponent
	Rem Feuille planning
	oFeuille1 = oMonClasseur.Sheets.getByName("planning")
	Rem Feuille DATA
	oFeuille2 = oMonClasseur.Sheets.getByName("DATA")
	
	Rem Récupération du nombre de personne dans DATA
	oNbPersonne = oFeuille2.getcellrangebyname("C2").value
	
	Rem Nombre de colonne à explorer sans la première
	' A modifier en cas d'ajout ou de suppression de colonne
	oNbColonne = 7
	Rem Nombre de ligne à explorer sans la première
	' A modifier en cas d'ajout ou de suppression de ligne
	oNbLigne = 43
			
	Rem On extrait la valeur des cellules du planning et on les compares avec les noms pour leur affecter un style perso
	for oCol = 1 to oNbColonne
		for oLign = 1 to oNbLigne
			Rem On récupère les valeurs des cellules dans la feuille planning
			oCellule1 = oFeuille1.getCellByPosition(oCol, oLign).string
			oPersPlanning = oCellule1
			
			if oCellule1 <> "" Then
				Rem On cherche le nom de la personne dans DATA 
				for oCompteur = 2 to oNbPersonne + 1
					Rem On passe la liste en revue pour comparer avec le contenu du planning
					oCellule2 = oFeuille2.getcellrangebyname("A" & oCompteur).string
					oPesonnel = oCellule2
					
					Rem SI le nom de la personne sur le planning identique à la liste 
					' ALORS on décal pour récupérer la couleur ou la mise en forme
					if StrComp(oPersPlanning, oPesonnel , 1) = 0 Then
					'	msgbox(oCellule1 & " sur " & oCellule2)
						Rem On récupère la couleur
						oLaCouleur  = oFeuille2.getcellrangebyname("B" & oCompteur).string
					
						Rem On appel la routine ChangeCouleur()
						call ChangeCouleur(oLaCouleur, oCol, oLign)
						'On quitte la boucle
						exit for
					endif
				Next oCompteur
			EndIf
		Next oLign				
	Next oCol
end sub


Rem Routine qui va affecter le style à nos cellules
sub ChangeCouleur(LaCouleur, col, lign)
	
	Rem appel de la cellule du planning pour affectation de la couleur
	oCellule1 = oFeuille1.getCellByPosition(col, lign)
	
	select case LaCouleur   
	case "rouge"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "rouge"

	case "bleuFonce"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "bleuFonce"

	case "rose"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "rose"
	
	case "vertFonce"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "vertFonce"
	
	case "mauve"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "mauve"
	
	case "orange"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "orange"
	
	case "vertClair"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "vertClair"
	
	case "marron"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "marron"
	
	case "bordeaux"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "bordeaux"

	case "bleuClair"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "bleuClair"
	
	case "gris"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "gris"

	case "contourRouge"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "contourRouge"

	case "contourVert"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "contourVert"

	case "contourBleu"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "contourBleu"

	case "contourRose"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "contourRose"
	
	case "ContourOrange"
	     Rem Affectation du style crée
	     oCellule1.CellStyle = "ContourOrange"
	
	end select ' Fin de Select

	Rem Pour ajouter une couleur ajouter un ligne comme ci-dessous
	' Mettre le nom du style (penser à le faire aussi dans DATA à côté du nom de la personne)
	'	case "NomDuStyle"
	     Rem Affectation du style crée
	 '    oCellule1.CellStyle = "NomDuStyle"
End Sub

Dernière modification par Kéral (Le 07/11/2007, à 12:52)

silver74

Re : besoin d'aide pour adapter une macro excel pour OO-calc

Purée te vraiment un chef,merci bcp
Je vais tester ca toute suite,pendant ma pause midi

Dernière modification par silver74 (Le 07/11/2007, à 13:32)

---

"Lorsque tu as découvert le libre, tu sais que tu ne pourras plus jamais revenir en arrière"