Contenu | Rechercher | Menus

Annonce

Si vous avez des soucis pour rester connecté, déconnectez-vous puis reconnectez-vous depuis ce lien en cochant la case
Me connecter automatiquement lors de mes prochaines visites.

À propos de l'équipe du forum.

#1 Le 14/01/2022, à 13:04

steph babat 14

[Résolu] calc, faire une feuille d'anniversaires

Bonjour,

Je désire faire un pense bête pour les anniversaire de la famille et dans la colonne « age » je voudrai avoir : xxans, xxmois, xxjours et je n’y arrive pas

calc anniv

- en F7 j’ai écris le résultat à la main
- en F8 j’ai fait =E8-E3

J’ai essayé avec les fonctions : aujourdhui, maintenant, texte, somme, je ne sais pas comment faire pour avoir la différence entre la date du jour et la date de naissance.

Pouvez vous m’aider merci

Stéph

Dernière modification par steph babat 14 (Le 29/01/2022, à 01:14)


(64bits)-Ubuntu 18.04.5 LTS_Gnome : 3.28.2 # Processeur : Intel® Core™ i5-8600 CPU @ 3.10GHz (6 cœurs) # Mémoire : 15,6 Gio (2x 8 Gio) # Carte-Graphique : GeForce GTX 1050/PCIe/SSE2

Hors ligne

#2 Le 14/01/2022, à 14:22

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour

Dans la cellule F7 (l'age de mamie)
entre (ou copie/colle) la formule suivante :

=DATEDIF(E7;E$3;"y") & " ans " & DATEDIF(E7;E$3;"ym") & " mois et " & DATEDIF(E7;E$3;"md") & " jours"

puis sélectionne la cellule F7 et clique sur le carré noir qui est en bas à droite de la cellule sélectionnée pour le faire glisser en bas à droite de la cellule F8
ou plus bas si tu as entré d'autres dates de naissance dans les cellules en dessous de E8

Ce qui donne :
Capture-d-cran-2022-01-14-14-24-21.png<- Cliquez sur l'image pour la voir en taille réelle.
J'espère que mamie ne m'en voudra pas de l'avoir fait vieillir d'une journée,
c'était juste pour tester le fonctionnement de la formule entrée smile


Modération : merci d'utiliser des images de petite taille (300x300) ou des miniatures pointant sur ces images.

Dernière modification par cqfd93 (Le 14/01/2022, à 15:52)

Hors ligne

#3 Le 14/01/2022, à 21:20

steph babat 14

Re : [Résolu] calc, faire une feuille d'anniversaires

DATEDIF, je ne l'avais pas trouvé celui là!

Un grand merci MicP pour la formule toute faite, je pensais y passer une partie de la soirée smile

À quoi sert le symbole $ dans la formule? je l'ai enlevé pour tester et ça fait le même résultat...

Encore merci


(64bits)-Ubuntu 18.04.5 LTS_Gnome : 3.28.2 # Processeur : Intel® Core™ i5-8600 CPU @ 3.10GHz (6 cœurs) # Mémoire : 15,6 Gio (2x 8 Gio) # Carte-Graphique : GeForce GTX 1050/PCIe/SSE2

Hors ligne

#4 Le 14/01/2022, à 21:36

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

EDIT : Tout faux : je me suis planté dans mes explications

… À quoi sert le symbole $ dans la formule? …

S'il n'était pas là, il te faudrait changer 3 en 4 et en 5 pour l'adapter à la formule copiée dans chaque ligne
tandis qu'avec ce caractère, tu n'as plus qu'à sélectionner la cellule F7 et cliquer sur le petit carré noir (qui est en bas à droite de la cellule sélectionnée) pour faire "glisser" ce petit carré noir aussi bas que tu veux
pour copier la même formule dans toutes les cellules et que le 3 (qui indiquait la ligne) change en 4 pour la même formule qui sera copiée dans la ligne 4, etc.

Voir : Adresses et références absolues et relatives

… je l'ai enlevé pour tester et ça fait le même résultat...

Du coup, tu sera obligé de changer le 3 en 4 etc pour chaque ligne dans laquelle tu copiera la formule,
tandis qu'en faisant une copie comme ça, la formule s'adaptera automatiquement au numéro de la ligne.

Voir plus bas

Dernière modification par MicP (Le 14/01/2022, à 22:01)

Hors ligne

#5 Le 14/01/2022, à 21:45

nany

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour,



Euh… C’est plutôt l’inverse, le dollar préserve le numéro de ligne lors de la copie.


Petite précision, le petit carré noir est appelé poignée de recopie.

Hors ligne

#6 Le 14/01/2022, à 21:51

sarthi

Re : [Résolu] calc, faire une feuille d'anniversaires

steph babat 14 a écrit :

...

À quoi sert le symbole $ dans la formule? je l'ai enlevé pour tester et ça fait le même résultat...

...

Cela permet un meilleur contrôle des références des cellules. Voir Wiki LibreOfficce Calc : Adresses et références : absolues et relatives

Hors ligne

#7 Le 14/01/2022, à 21:55

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Ah beh oui, je ne sais pas comment je me suis débrouillé, mais je me suis complètement planté dans mes explications,
(j'avais fait ça à 14:44 et j'étais levé depuis 05:00, et je tente de l'expliquer à 21:36, du coup, il va me falloir aller me reposer lol)

C'est bien la cellule E3 dont la ligne va rester constante dans la formule, puisqu'il s'agit de celle qui sert de référence comme date d'aujourd'hui.
(j'aurais dû garder mon fichier de test, je l'avais effacé vers 15:00)

Le lien que j'avais donné l'explique très bien.

Merci nany smile

=======
NOTE :
Si tu veux te passer de la référence à la cellule E3
tu peux remplacer la formule qui est dans la cellule F7 par :

=DATEDIF(E7;AUJOURDHUI();"y") & " ans " & DATEDIF(E7;AUJOURDHUI();"ym") & " mois et " & DATEDIF(E7;AUJOURDHUI();"md") & " jours"

Dernière modification par MicP (Le 14/01/2022, à 22:12)

Hors ligne

#8 Le 15/01/2022, à 13:42

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour

J'ai bien dormi, big_smile
alors ce matin, j'en ai profité pour améliorer un peu ce qui s'affiche dans la colonne age
parce que ça m’agaçait de voir s'afficher "1 ans"  et "1 jours"

Pour simplifier la lisibilité des formules, j'ai inséré les 3 colonnes F, G et H
que j'ai laissées visibles dans la capture d'écran ci-dessous mais qui pourront êtres masquées en réduisant au minimum leur largeur.
(elles sont d'ailleurs masquées sur le document que j'ai rendu accessible en téléchargement)

Capture-d-cran-2022-01-15-13-59-23.png
Ce fichier Libre Office Calc est accessible en cliquant sur le lien suivant PourStephBabat14Ubuntu-fr.ods (16KB)

Formule dans la cellule E3 :

=AUJOURDHUI()

Formule dans la cellule F7 (et toutes les cellules en dessous en adaptant le n° de la ligne concernée) :

=DATEDIF(E7;E$3;"y")

Formule dans la cellule G7 (et toutes les cellules en dessous en adaptant le n° de la ligne concernée) :

=DATEDIF(E7;E$3;"ym")

Formule dans la cellule H7 (et toutes les cellules en dessous en adaptant le n° de la ligne concernée) :

=DATEDIF(E7;E$3;"md")

Formule dans la cellule I7 (et toutes les cellules en dessous en adaptant le n° de la ligne concernée) :

=SI(E7="";"";SI(F7>0;SI(F7=1;"1 an";F7 & " ans");"") & SI(G7+H7>0;SI(F7>0;SI(ET(G7>0;H7>0);", ";" et ");"");"") & SI(G7>0; G7 & " mois";"") & SI(G7>0;SI(H7>0;" et ";"");"") & SI(H7=0;"";SI(H7=1;"1 jour";H7 & " jours")))

Dernière modification par MicP (Le 15/01/2022, à 15:09)

Hors ligne

#9 Le 16/01/2022, à 10:38

steph babat 14

Re : [Résolu] calc, faire une feuille d'anniversaires

Merci pour ces infos et démonstrations, je me sers souvent de Calc avec des formules simples.

Donc si je continue, je dois pouvoir faire une formule qui me donne directement le résultat de la colonne "I"

Et bé on va essayer

merci encore


(64bits)-Ubuntu 18.04.5 LTS_Gnome : 3.28.2 # Processeur : Intel® Core™ i5-8600 CPU @ 3.10GHz (6 cœurs) # Mémoire : 15,6 Gio (2x 8 Gio) # Carte-Graphique : GeForce GTX 1050/PCIe/SSE2

Hors ligne

#10 Le 16/01/2022, à 11:03

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour

J'ai créé un nouveau fichier comme celui que tu présentais dans ton premier message :

Capture-d-cran-2022-01-16-12-15-25.png

Mais j'ai entré dans la cellule F7 la formule suivante :

=SI(E7="";"";SI(DATEDIF(E7;E$3;"y")>0;SI(DATEDIF(E7;E$3;"y")=1;"1 an";DATEDIF(E7;E$3;"y") & " ans");"") & SI(DATEDIF(E7;E$3;"ym")+DATEDIF(E7;E$3;"md")>0;SI(DATEDIF(E7;E$3;"y")>0;SI(ET(DATEDIF(E7;E$3;"ym")>0;DATEDIF(E7;E$3;"md")>0);", ";" et ");"");"") & SI(DATEDIF(E7;E$3;"ym")>0; DATEDIF(E7;E$3;"ym") & " mois";"") & SI(DATEDIF(E7;E$3;"ym")>0;SI(DATEDIF(E7;E$3;"md")>0;" et ";"");"") & SI(DATEDIF(E7;E$3;"md")=0;"";SI(DATEDIF(E7;E$3;"md")=1;"1 jour";DATEDIF(E7;E$3;"md") & " jours")))

Une fois la formule ci-dessus entrée dans la cellule F7,
j'ai utilisé la poignée de recopie pour recopier cette formule dans les cellules qui sont en dessous.

Voici le lien vers le fichier utilisant la formule ci-dessus.

=======
NOTE : La formule entrée dans la cellule F7 est dépendante de la valeur de la cellule E3 qui est à droite de la cellule D3 dans laquelle on voit s'afficher: date du jour :

Si tu veux que la formule de la cellule F7 ne soit dépendante que de la valeur contenue dans la cellule E7
il faudra remplacer dans l'ancienne formule toutes les références à la cellule E3 par le résultat de la fonction AUJOURDHUI()

Dans ce cas, il te faudra changer la formule contenue dans la cellule F7
par la formule suivante :

=SI(E7="";"";SI(DATEDIF(E7;AUJOURDHUI();"y")>0;SI(DATEDIF(E7;AUJOURDHUI();"y")=1;"1 an";DATEDIF(E7;AUJOURDHUI();"y") & " ans");"") & SI(DATEDIF(E7;AUJOURDHUI();"ym")+DATEDIF(E7;AUJOURDHUI();"md")>0;SI(DATEDIF(E7;AUJOURDHUI();"y")>0;SI(ET(DATEDIF(E7;AUJOURDHUI();"ym")>0;DATEDIF(E7;AUJOURDHUI();"md")>0);", ";" et ");"");"") & SI(DATEDIF(E7;AUJOURDHUI();"ym")>0; DATEDIF(E7;AUJOURDHUI();"ym") & " mois";"") & SI(DATEDIF(E7;AUJOURDHUI();"ym")>0;SI(DATEDIF(E7;AUJOURDHUI();"md")>0;" et ";"");"") & SI(DATEDIF(E7;AUJOURDHUI();"md")=0;"";SI(DATEDIF(E7;AUJOURDHUI();"md")=1;"1 jour";DATEDIF(E7;AUJOURDHUI();"md") & " jours")))

Dernière modification par MicP (Le 16/01/2022, à 12:43)

Hors ligne

#11 Le 21/01/2022, à 22:45

steph babat 14

Re : [Résolu] calc, faire une feuille d'anniversaires

Salut,

J'adore cette feuille calc, un vrai bonheur.

J'essaie de la faire évoluer et d'avoir dans la colonne suivante (en G) le nombre de mois et jours avant le prochain anniversaire mais ce n'est pas gagné, "datedif" ne sait pas compter en arrière à moins que ce ne soit moi, je n'ai qu'un message "err:502"

Comment dois-je faire

Stéph


(64bits)-Ubuntu 18.04.5 LTS_Gnome : 3.28.2 # Processeur : Intel® Core™ i5-8600 CPU @ 3.10GHz (6 cœurs) # Mémoire : 15,6 Gio (2x 8 Gio) # Carte-Graphique : GeForce GTX 1050/PCIe/SSE2

Hors ligne

#12 Le 22/01/2022, à 12:33

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour

steph babat 14 a écrit :

… "datedif" ne sait pas compter en arrière …

Oui, et c'est logique puisqu'on n'a pas encore trouvé comment voyager dans le temps,
et d'ailleurs, si tu entres une date de naissance ultérieure à la date actuelle, la cellule correspondant à l'âge indiquera :Erreur 502

Les formules entrées dans la colonne G doivent donc tenir compte de la condition suivante :
si la date d'anniversaire dans l'année en cours est déjà dépassée, alors le prochain anniversaire aura lieu dans l'année suivante.

Capture-d-cran-2022-01-22-12-44-02.png

j'ai entré dans la cellule G7 la formule suivante :

=SI(ESTVIDE(E7);"";SI(DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"ym") >0;DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"ym") & " mois";"") & SI(ET(DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"ym")>0;DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"md")>0);" et "; "") & SI(DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"md")=0;"12 mois";DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"md") &" jour" & SI(DATEDIF(AUJOURDHUI();SI(E7<=AUJOURDHUI();DATE(ANNEE(AUJOURDHUI())+1;MOIS(E7);JOUR(E7));E7);"md")>1; "s";"")))

Une fois la formule ci-dessus entrée dans la cellule G7,
j'ai utilisé la poignée de recopie pour recopier cette formule dans les cellules qui sont en dessous.

Voici le lien vers le fichier (12Ko) utilisant la formule ci-dessus.

=======
[/HUMOUR]

Alors Oui, c'est vrai qu'il y a beaucoup de SI dans ces formules,
mais c'est parce que :

c'est en bûchant qu'on devient bûcheron
et
c'est en sciant que Léonard …

[/HUMOUR]

Dernière modification par MicP (Le 22/01/2022, à 14:56)

Hors ligne

#13 Le 22/01/2022, à 22:48

steph babat 14

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonsoir et merci beaucoup c’est exactement ce que je voulais.

Y aurait-il une méthode pour décomposer une formule pour que je la comprenne petit à petit ?  Parce que refaire quelque chose dans ce genre me reste inaccessible.

Par contre l'humour j'ai bien compris smile  c'est en sciant que Léonard …  devint sciant... lol haha le boulet tongue comme moi


(64bits)-Ubuntu 18.04.5 LTS_Gnome : 3.28.2 # Processeur : Intel® Core™ i5-8600 CPU @ 3.10GHz (6 cœurs) # Mémoire : 15,6 Gio (2x 8 Gio) # Carte-Graphique : GeForce GTX 1050/PCIe/SSE2

Hors ligne

#14 Le 23/01/2022, à 00:41

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

À non, c'était simplement : Léonard de Vinci

=======
Il est beaucoup plus simple de composer une aussi longue formule que de la décomposer.

Pour la composer, j'ai commencé par chercher les fonctions dont j'aurai besoin
et ensuite, j'ai décomposé la tâche en plusieurs parties.

J'ai trouvé la fonction DATEDIF et je suis allé lire la documentation la concernant
puis j'ai commencé à la tester dans plusieurs cas en créant une colonne remplie de dates différentes
pour tester tous les cas qui m'intéressaient, et lire la doc concernant les messages d'erreur retournés.

J'ai pu ainsi voir les limites de cette fonction en fonction de ce que je voulais obtenir,
alors j'ai commencé par lui faire extraire le jour, le mois et l'année dans trois colonnes différentes
que j'ai utilisées ensuite comme dans mon message #8

Puis j'ai continué ensuite à chercher les fonctions qui me manquaient pour arriver à mes fins petit à petit
en créant plusieurs colonnes dont je réutilisais le résultat dans les calculs suivants,
et j'ai procédé de même pour chaque nouvelle fonction dont j'ai eu besoin.

Si je n'en ai pas oublié, j'ai utilisé dans cette formule les 9 fonctions suivantes : ANNEE, AUJOURDHUI, DATE, DATEDIF, ESTVIDE, ET, JOUR, MOIS, SI

Au final, je n'avais plus qu'à remplacer, dans la cellule donnant le résultat attendu,
les références des cellules calculées à l'étape précédente, par la formule contenue dans cette cellule
comme je l'ai fait dans la feuille de calcul de mon message #8

Ce qui donne, au final cette longue formule.

=======
Bien sûr, je n'y suis pas arrivé du premier coup,
et j'ai plusieurs fois re-écrit certaines étapes
et parfois même tout recommencé à zéro.

Et je suis sûr qu'il y a des pros qui, en voyant cette formule vont trouver tout ça affreux
et qui, ayant une véritable expérience, utilisent d'autres méthodes plus fiables pour obtenir ce résultat.

D'autant que, n'ayant jamais eu aucune formation en bureautique ni en programmation informatique, je me débrouille comme je peux,
et comme je n'ai aucune expérience professionnelle, je manque sans aucun doute de méthode.

Dernière modification par MicP (Le 23/01/2022, à 16:16)

Hors ligne

#15 Le 23/01/2022, à 09:14

alex2423

Re : [Résolu] calc, faire une feuille d'anniversaires

MicP a écrit :

J'espère que mamie ne m'en voudra pas de l'avoir fait vieillir d'une journée,
c'était juste pour tester le fonctionnement de la formule entrée smile

Profites à fond de ta mamy smile, rends lui visites au maximum, demandes de parler son enfance, . Cela fait plaisir de voir qu'elle a 3 chiffres dans son age dont on se fiche éperdudément.

Hors ligne

#16 Le 23/01/2022, à 09:28

Compte supprimé

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour,
MicP a bien décrit sa méthode pour répondre à la question. Mais vous ne pouvez pas en rester là smile
steph babat 14 ne va quand même pas regarder ce fichier tous les jours pour savoir quel anniversaire il doit souhaiter tongue

Il reste à mettre en place un système qui le prévient automatiquement la veille de chaque anniversaire. Ou alors utiliser un logiciel "étudié pour".

#17 Le 23/01/2022, à 15:20

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Tamarou a écrit :

… mettre en place un système qui le prévient automatiquement la veille de chaque anniversaire. …

Pour le faire en utilisant cette feuille de  calcul,
il serait possible d'utiliser les scripts de libre office calc
mais il faudrait alors lancer libre office à chaque ouverture de session

Par contre, on pourrait utiliser les données de ce fichier sauvegardées au format CSV
et faire lire ce fichier CSV par un script bash qui sera lancé automatiquement à l'ouverture de session

Si je devais faire ça tout en bash je commencerai par me créer un fichier de notes
dans lequel je commence à poser des idées en vrac pour essayer d'organiser tout ça :

ouverture de session => lecture fichier csv pour comparer date actuelle + 1 jour à dates anniversaires
Si correspondances => affichage popup : " Demain, c'est l'anniversaire de xxxxx"

Script démarré à l'ouverture de session => fichier ~/.config/autostart/notificationAnniversaires.sh

Fichier CSV => fichier ~/.config/anniversaires.csv
     1er 2ème et 3ème champ -> Date au format "mm jj aaaa" (date -d "dateSaisie" "+%m;%d;%Y")
     4ème champ -> "Prénom(s)"
     5ème champ -> "Nom(s)"

Recherche si anniversaire demain
   - ajout de +1 jour à la date d'aujourd'hui (date -d "+1 day" "+%m;%d;%Y")
   - Boucle for de recherche dans le fichier CSV pour extraction des lignes dont le premier champ et deuxième correspondent respectivement à "mm" et "jj"
   - S'il y a des lignes extraites, alors :
       - calcul de l'age (année_actuelle - année_naissance)
       - préparer les lignes du message : "Age Prénom(s) Nom(s)"
       - notify-send messageÀafficher

Ajout d'un enregistrement dans le fichier CSV
   - saisie Nom + Prenom
     - test si présence de caractère(s) interdits(s) sinon bouclage => faire la liste des caractères interdits
   - saisie date naissance :
     - test si date existe sinon bouclage (date -d AnnéeMoisJour)
   - ajout d'un enregistrement dans le fichier CSV

Suppression d'un enregistrement dans le fichier CSV
   - saisie motif de recherche Nom + Prenom
   - ou/et :
   - saisie motif de recherche date naissance ou/et nom ou/et prénom (regex)
   - recherche et affichage occurences trouvées dans le fichier CSV
   - S'il y a des enregistrements trouvés, alors :
        - saisie sélection des enregistrements à supprimer
        - suppression enregistrement(s)

Format d'en enregistrement :
"12;31;2000;Anne-Sophie;de la Coquillette"

monEnregistrement="12;31;2000;Anne-Sophie;de la Coquillette"
maReg='(.*);(.*);(.*);(.*);(.*)'
[[ $monEnregistrement =~ $maReg ]]
varMois=${BASH_REMATCH[1]}
varJour=${BASH_REMATCH[2]}
varAnnee=${BASH_REMATCH[3]}
varPrenom=${BASH_REMATCH[4]}
varNom=${BASH_REMATCH[5]}

Et petit à petit, je teste quelques lignes de commandes
pour réajuster tout ça en fonction de ce que ça donne et de ce que je veux obtenir.


=======
Au final, en fonction de l'abonnement téléphonique,
un SMS pourrait être automatiquement envoyé pour souhaiter l'anniversaire.

Dernière modification par MicP (Le 23/01/2022, à 16:10)

Hors ligne

#18 Le 23/01/2022, à 17:03

steph babat 14

Re : [Résolu] calc, faire une feuille d'anniversaires

Léonard …  devint sciant… c’est du second degrés lol

Wahou  j’ai été doublé, dans le sens où je n’en voulais pas tant…

Étant un être de type homme du sexe masculin j’oublie fréquemment les dates d’anniversaire, pas oublier mais à quelques jours près et ça fait toute la différence surtout avec la gente féminine. Pareil avec la date du jour ; Alors pour parer à cette lacune j’ai besoin d’une aide ponctuelle et simple avec la date précise. Et comme avec les jeunes entre 7 et 18ans il faut être précis au nombre de jour près avant leur anniversaire surtout quand on les a au téléphone, j’ai enfin ma parade, j’ouvre mon fichier anniversaire en loucedé et je peux communiquer en toute quiétude… forcement je l’ouvre quelques jours avant pour contrôler.

_  Pour moi ce fichier calc est suffisant, je n’ai pas besoin d’une machine ou d’un programme dédié pour retenir les dates à ma place _

merci à tous

MicP ça à du être long toute la démarche pour parvenir au résultat, et toutes ces explications bravo et merci pour ton aide

Stéph

Dernière modification par steph babat 14 (Le 23/01/2022, à 17:06)


(64bits)-Ubuntu 18.04.5 LTS_Gnome : 3.28.2 # Processeur : Intel® Core™ i5-8600 CPU @ 3.10GHz (6 cœurs) # Mémoire : 15,6 Gio (2x 8 Gio) # Carte-Graphique : GeForce GTX 1050/PCIe/SSE2

Hors ligne

#19 Le 23/01/2022, à 17:39

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

… j’oublie fréquemment les dates d’anniversaire, pas oublier mais à quelques jours près et ça fait toute la différence surtout avec la gente féminine …

Quelques liens à ce sujet :

http://mpailhe.free.fr/videos/a0ZKmrd_460svav1.mp4

http://mpailhe.free.fr/videos/aze8bGB_460svav1.mp4

=======

…MicP ça à du être long toute la démarche pour parvenir au résultat, et toutes ces explications  …

Pas tant que ça, vu que j'avais déjà mentalement fait chaque élément que j'ai utilisé
le plus long pour moi a été d'arriver à l'écrire et l'expliquer.

Dernière modification par MicP (Le 23/01/2022, à 19:09)

Hors ligne

#20 Le 23/01/2022, à 18:58

lool_lauris

Re : [Résolu] calc, faire une feuille d'anniversaires

Salut,

Alternative (peut-être !?) :

Le carnet d'adresses de Thunderbird permet, pour chaque contact, de renseigner la date de naissance. Si l'on combine cela avec cette extension, on doit pouvoir maintenir et être averti des dates anniversaires à venir.

EDIT : je ne l'ai personnellement pas testée.

Dernière modification par lool_lauris (Le 23/01/2022, à 20:06)


Soutenez le Libre => http://www.april.org/

Hors ligne

#21 Le 23/01/2022, à 20:02

Compte supprimé

Re : [Résolu] calc, faire une feuille d'anniversaires

Alternative (peut-être !?) :

Oui, c'est pour cela que plus haut je suggérais l'usage d'une solution "étudiée pour".
Ça fonctionne très bien, et je lai testé, avec les contacts et agendas d' Evolution et c'est certainement la même chose avec Thunderbird.

Mais ce n'est pas ce que cherche steph babat 14.
Bonne soirée à tous.

#22 Le 23/01/2022, à 21:00

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour

Tout est faisable, mais faut voir le format d'export possible de ces carnets d'adresse.
et puis ce qui est demandé, et surtout, voir d'abord ce qu'il existe déjà tout fait
et qui est sans doute bien mieux fait que je ne pourrais faire.

Hors ligne

#23 Le 23/01/2022, à 21:21

lool_lauris

Re : [Résolu] calc, faire une feuille d'anniversaires

Mais pourquoi vouloir exporter les données ? En fait, le truc est totalement intégré : les données sont intégrées au carnet TBird et l'extension fait le job !
Et dans ce cas, pas besoin de feuille de calcul. smile

Dernière modification par lool_lauris (Le 23/01/2022, à 21:24)


Soutenez le Libre => http://www.april.org/

Hors ligne

#24 Le 24/01/2022, à 08:45

MicP

Re : [Résolu] calc, faire une feuille d'anniversaires

Bonjour

Dans son message #16, Tamarou a écrit :

… Il reste à mettre en place un système qui le prévient automatiquement la veille de chaque anniversaire. …

Étant donné que le titre de ce fil de discussion concerne LibreOffice Calc,
autant faire afficher le message listant les anniversaires à souhaiter le lendemain par Calc.

J'avais oublié que l'on peut lancer LibreOffice Calc depuis la ligne de commande,
donc, il reste à créer une macro qui fera le travail d'extraction des noms/prénoms dont l'anniversaire est pour le lendemain
et qui affichera (si possible) le message.
Mais comme ça fait très très longtemps que je n'ai pas créé de macro dans une feuille de calcul,
ça va pas être pour tout de suite…

=======
Donc, je laisse tomber le script bash, car je suis hors sujet.
(Si ça intéresse quelqu'un, je reprendrais le script commencé dans mon message #17, mais dans un autre fil de discussion)

Hors ligne

#25 Le 24/01/2022, à 10:07

Compte supprimé

Re : [Résolu] calc, faire une feuille d'anniversaires

@MicP
C'était une façon plus allusive de dire la même chose que lool_lauris.
Mais j'ai bien aimé ta façon d'expliquer comment tu as recherché les formules pour le tableur.